The tool of thought for expert programming

|  |
| --- |
| pdfgreyline |

Futures and Isolates  
  
or  
  
Experimental Parallel Language Features in Dyalog APL Version 14.0

Dyalog Limited

Minchens Court, Minchens Lane  
Bramley, Hampshire  
RG26 5BH  
United Kingdom

tel: +44(0)1256 830030

fax: +44 (0)1256 830031  
email: [support@dyalog.com](mailto:support@dyalog.com)  
http://www.dyalog.com

Dyalog is a trademark of Dyalog Limited  
Copyright © 1982-2014  


Dyalog is a trademark of Dyalog Limited  
Copyright © 1982 - 2014 by Dyalog Limited.  
All rights reserved.

Version 14.0

Revision: 20140311\_140

No part of this publication may be reproduced in any form by any means without the prior written permission of Dyalog Limited, Minchens Court, Minchens Lane, Bramley, Hampshire, RG26 5BH, United Kingdom.

Dyalog Limited makes no representations or warranties with respect to the contents hereof and specifically disclaims any implied warranties of merchantability or fitness for any particular purpose. Dyalog Limited reserves the right to revise this publication without notification.

UNIX is a registered trademark of The Open Group.  
  
All other trademarks and copyrights are acknowledged.

Contents

[1 Introduction 1](#_Toc386000842)

[2 Philosophical Preamble 2](#_Toc386000843)

[2.1 Parallel Language Features in Dyalog APL 2](#_Toc386000844)

[2.2 Automatic Parallelization 2](#_Toc386000845)

[2.3 Explicit Parallelization 3](#_Toc386000846)

[3 Introducing Futures and Isolates 4](#_Toc386000847)

[3.1 Isolates 4](#_Toc386000848)

[3.2 Futures 5](#_Toc386000849)

[3.3 Parallel Operator 6](#_Toc386000850)

[4 Getting Started 7](#_Toc386000851)

[4.1 Parallel Each 7](#_Toc386000852)

[4.2 Explicit Isolates 9](#_Toc386000853)

[4.3 A More Realistic Example 9](#_Toc386000854)

[5 Configuration 11](#_Toc386000855)

[5.1 Configuration Options 11](#_Toc386000856)

[5.1.1 debug 11](#_Toc386000857)

[5.1.2 drc 11](#_Toc386000858)

[5.1.3 workspace 12](#_Toc386000859)

[5.1.4 listen 12](#_Toc386000860)

[5.1.5 processors 12](#_Toc386000861)

[5.1.6 processes 12](#_Toc386000862)

[5.1.7 runtime 12](#_Toc386000863)

[6 Advanced Topics 13](#_Toc386000864)

[7 Troubleshooting 14](#_Toc386000865)

[7.1 Differences between Isolates and Namespaces 14](#_Toc386000866)

[7.1.1 Trapped Errors 14](#_Toc386000867)

[7.1.2 Unexpected Output 14](#_Toc386000868)

[7.1.3 File Ties Not Shared with Isolates 14](#_Toc386000869)

[8 Debugging Isolates 15](#_Toc386000870)

[Appendix A: Function and Operator Reference 16](#_Toc386000871)

[r←StartServer ⍵ 16](#_Toc386000872)

[r←AddServer ⍵ 16](#_Toc386000873)

[r←New ⍵ 17](#_Toc386000874)

[r←Config ⍵ 17](#_Toc386000875)

[3.2 Operators 17](#_Toc386000876)

[r←⍺ (⍺⍺ ll) ⍵ 17](#_Toc386000877)

[r←⍺ (⍺⍺ llEach) ⍵ 17](#_Toc386000878)

[r←⍺ (⍺⍺ llOuter) ⍵ 18](#_Toc386000879)

[r←⍺ (⍺⍺ llRank ⍵⍵) ⍵ 18](#_Toc386000880)

[Appendix Z: Implementation Notes 19](#_Toc386000881)

# Introduction

Dyalog believes that the isolate workspace and language support for futures are now close to complete, but this document was still very much “work in progress” at the time that Beta 4 was shipped. If you are interested in testing these features, write to [beta140@dyalog.com](mailto:beta140@dyalog.com) to register your interest in receiving updated documentation as it becomes available.

This document describes proposals for two new primitives, and a new type of array, designed to allow APL developers to take advantage of multiple processors to execute code in parallel:

* The function “isolate” (**¤**), which creates a special kind of namespace known as an *isolate*, inside which all APL language statements are executed in parallel with the main APL process.
* The monadic operator “parallel” (**∥**), which derives a function that will execute the left operand in an empty isolate.
* A new type of array known as a “future”, which is a pointer to the future result of an expression currently being executed in an isolate. Futures can be passed around as function arguments and as items of nested arrays, but will “block” any expression which actually needs the value pointed to by the future.

In version 14.0, futures are implemented as a new primitive feature supported by the interpreter. The isolate function and the parallel operator are provided as models which are partly implemented in APL, provided in the distributed workspace ws\isolate.dws.

**Important:** Although version 14.0 only provides a model, Dyalog believes that the design is very close to being complete, and urges all users with applications containing potential parallelism to make use of the experimental implementation, to help confirm the design and reveal any weaknesses that need to be worked on in the final implementation as part of the core language.

The current plan (subject to change without notice) is to produce a revised model based on user feedback for version 14.1, and a fully “primitive” implementation in version 15.0.

# Philosophical Preamble

This section contains a discussion of issues surrounding the parallelisation of APL code. If you are looking to quickly get started with using futures and isolates, skip to section 3.

### Parallel Language Features in Dyalog APL

Ever since the first implementation, Dyalog APL has included many language features which are parallel in nature, although the implementations did not perform actual parallel execution:

* Most primitive functions work on arrays, performing operations on all the elements of argument(s).
* Many classical primitive operators from APL2 such as each (f¨), inner product (f.g), outer product (∘.g), and some reductions (f/) and scans (f\), express repeated and thus potentially parallel execution of one or more functions.
* New operators added to Dyalog APL more recently, such as rank (f⍤n), key (f⌸), and even some uses of the power operator (f⍣g), also express potentially parallel operations.
* In Dyalog APL, the use of the dot to execute an expression within the scope of an array of objects or namespaces, expresses potentially parallel execution (namespaces.foo).

Until recently, none of the above language constructs caused actual parallel execution. Starting with version 14.0, Dyalog intends to give high priority to implementing actual parallel execution of APL language statements.

There are two main tracks to pursue:

* Automatic parallelization, where the interpreter automatically infers that a ”traditional” APL language statement can be parallelised, and automatically decides to execute code in parallel when this will improve the performance of an application.
* Explicit parallelization, where the language provides new mechanisms that allow the programmer to declare that certain parts of the application could or should be executed in parallel.

### Automatic Parallelization

Given the number of parallel language construct in the APL language, it might appear that automatic parallelisation should be easy to implement. In fact, parallel execution of a number of scalar dyadic functions on floating-point arguments was introduced in version 12.1 of Dyalog APL, and some user applications did realise noticeable speed-ups. However, automatic parallelisation of traditional APL expressions faces a number of significant challenges:

1. Most arguments are small: Parallel execution has a set-up time to start parallel threads or processes, and a synchronization cost when the results computed by separate processes are coalesced into a single array result. In typical real applications, the arguments to most primitive functions only have a very small number of elements. Any potential speed-up from parallel execution will be lost in the setup
2. Cost of memory access: Although it is common for modern hardware to have multiple cores, the memory cannot support many cores reading or writing significant volumes of data simultaneously: a queue will form. Thus, operations which perform small quantities of processing compared to data movement (such as adding or multiplying large arrays), cannot be parallelized efficiently on current hardware.
3. Side-effects: When operator expressions are applied to user-defined functions, those functions can have side-effects. Many existing applications rely on the current order of execution of operator expressions and would fail or produce incorrect results if user-defined functions started executing in parallel.

Successful automatic parallelization on existing hardware will require and APL language system which is able to coalesce multiple primitive APL operations into larger units which can be effectively executed in parallel – plus the ability to detect that user-defined functions are free from side-effects. Dyalog is conducting and funding research into these areas and does expects to increase the amount of automatic parallelization that Dyalog APL supports.

However, in the short term, explicit parallelization though futures and isolates promise to provide more “bang for the buck” for the application developer.

### Explicit Parallelization

As mentioned in the previous section, it can be difficult for the APL engine to determine whether parallelization is both safe and worthwhile. However, in many cases the programmer will know where the potential for significant parallel execution lies in an application, and be able to identify sections of code that are free of side-effects (or able to “manage” any side-effects that might exist) - and represent enough work for the setup and synchronization costs to be worthwhile.

In the past, many languages have provided language extensions[[1]](#footnote-1) aimed at allowing parallel processing. These have typically depended on the programmer to make use of explicit synchronization features such as “semaphores”, which allow threads to mutually exclude each other from interfering with each other as they modify shared data, notify each other of progress, and wait for the one step to complete before a dependent task can be started. These features are notoriously difficult to use and often give rise to deadlocks and other difficult-to-detect defects in code, even when used carefully.

The challenge is to come up with new language features which make it easy for APL users to introduce parallelism, without reducing the readability of the code – and without making the application fragile and prone to synchronization of timing errors.

This has been the main design goal for futures and isolates.

# Introducing Futures and Isolates

*Futures* and *Isolates* are extensions to the APL language which are intended to provide the APL programmer with mechanisms for expressing the existence of potentially parallel sections of code in a *deterministic* fashion. Briefly:

* An *isolate* is a namespace which is semantically equivalent to a normal namespace, except that expressions which are executed inside an isolate can run in parallel (in a separate process) to the main application process. The current proposal is to create isolates using a new primitive function ¤ (isolate).
* A *future* is an array of unknown rank, shape and content, which is returned as the result of any expression that is executed inside an isolate. Futures can be passed as arguments to user-defined functions and arrays containing futures can be subject to structural transformations such as reshape or partitioned enclose, without blocking. Blocking (until the isolate manufactures a result) occurs if a future is passed to a function which needs to know the actual value (for example, a mathematical primitive function).

Between them, futures and isolates make it easy to divide application code into sections which can run in parallel: If one function required the result of code which is still executing in parallel, the “dependent” function will automatically wait until the data that it needs is available.

### Isolates

An isolate created using ¤ is almost identical to a namespace created using ⎕NS. The contents of an isolate can be referenced using the same “dot notation” that is used to refer to the contents of a regular namespace – and it is possible for code running inside an isolate to refer back to the parent space using the ## (Parent) symbol. However, isolates reside in separate processes and do not share a common workspace with the main process, and this does introduce some restrictions.

The most important differences between isolates and namespaces are the features that make isolates a tool for simple implementation of parallel execution within an application:

* Any evaluation which occurs within an isolate is handled in a separate process. If more than one processor is available, expressions inside isolates will run in parallel with the main process. If more than one isolate exists, execution proceeds independently within each isolate.
* An expression executed within an isolate immediately returns a *future*, without waiting for the expression to finish execution. A future is a placeholder for an as yet un-computed value (see section 3.2 for more information). The future automatically turns into a real value when the expression produces a result.

A number of differences are due to the fact that the isolate is actually inside a separate process. Although the contents – both code and data – are “only a dot away”, there are some restrictions on making references between isolates (or they would not deserve the name).

* Because the isolate is running in a separate process, it does not share file ties or any process-related handles or resources with its parent process[[2]](#footnote-2).
* Inside an isolate, the special symbol ## (aka “Parent”) can be used to refer to the root of the parent processes workspace. In a namespace, it would refer to the space inside which the isolate was created.
* Code running inside an isolate can ***only*** refer to spaces that are not contained within itself ***via*** the root of the parent workspace (referenced using ##, as mentioned above). You cannot pass a reference to something contained within one isolate to another isolate.

A handful of differences are due to the current implementation. These may disappear or change as we collect feedback and the implementation improves and eventually becomes completely integrated with the interpreter. Examples of these differences include:

* Expressions which produce a shy result when executed in a namespace may no longer be shy when executed in an isolate, because a future was returned and was “materialised” in a subsequent step – for session display. For example: nsref.(X←42).
* By default, errors occurring within an isolate will be trapped and reported to the calling environment. See the section 4 for information on how to disable error trapping and debug errors inside isolates.

### Futures

A future is an array of unknown rank, shape and content, which is returned as the result of any expression that is executed inside an isolate. Futures have the following characteristics:

* A future can be assigned to a variable, passed as the argument to a function or operator, stranded together with other elements to form an array, or be inserted into a nested array, while remaining a future (with unknown content).
* Arrays *containing* nested (enclosed) futures can be passed as arguments to user-defined functions or operators, or subjected to primitive structural functions such as reshape or compress, so long as no function which needs to know the shape or content of the future is encountered.
* If a primitive or system function which needs to reference the contents of the future is encountered, an attempt is made to display the future in the session, or pass it to an external program such as a Microsoft.Net method or a shared library function, the current thread will suspend until the expression which produced the future completes, and an actual value is assigned.

In other words, future results of expressions that are currently being executed inside one or more isolates (which are running in separate processes) can be passed around an application until the actual values are needed for the next computational step, at which point the code (the thread) that needs it will automatically block until the value is available.

Together, isolates and futures are designed to make it straightforward to write applications which contain sections that can run in parallel. No semaphores or special mechanisms are required to synchronize the independent expressions: When a result that is being computed asynchronously is required, the “consume” of this result will simply wait until it can proceed.

### Parallel Operator

Parallel (∥) is a monadic operator which returns a derived function which will immediately return a future, and execute the operand function within an empty isolate: It provides a mechanism for parallel execution of a function without the overhead of explicitly creating an isolate.

The parallel operator is typically combined with each (¨), in which case the operand function is invoked multiple times. For example, the elapsed time for the following expression should be slightly more than 3 seconds (without the parallel operator, it would be roughly 12 seconds):

⎕DL ∥¨3 3 3 3  
3.003 3.004 3.003 3.003

The temporary isolate is empty when the function starts running: the operand function may create global names for its own use, but they will be discarded together with the temporary isolate.

# Getting Started

While the ability to deal with the new type of array known as a future is a primitive feature of Dyalog APL version 14.0, the mechanisms for the creation of isolates and the execution of expressions within them are modelled in APL with the help of some undocumented I-Beams.

The model can be found in the distributed workspace ws\isolate.dws, in the form of a namespace called isolate, a function called ø and an operator named IÏ. The following functions and operators expose models of future primitive functions or operators:

|  |  |  |
| --- | --- | --- |
| **Name (within #.isolate)** | **Primitive Equivalent** | **Description** |
| New ''|*ns* | ¤ arg | Creates a new isolate – empty or cloned from ns |
| f ll | f∥ | Parallel operator |
| f llEach | f∥¨ | Equivalent of Parallel Each |
| f llOuter | ∘.(f∥) | Parallel outer product |
| f llRank m | (f∥)⍤m | Parallel rank operator[[3]](#footnote-3) |
| f llKey | (f∥)⌸⌸ | Parallel key operator3 |

The isolate namespace exposes the functions Config, AddServer and StartServer, which allow the setting of configuration options and the ability to start and use “remote” isolate servers. For more on these, see section 5.

Finally, the following global names are defined as shortcuts to the two most commonly used names in the isolate namespace, in order to provide closer visual fidelity with the final expressions that will use primitives.

|  |  |
| --- | --- |
| Name | Description |
| ø | Model of ¤ function (cover for isolate.New) |
| IÏ | Model of ∥¨ (cover for isolate.llEach) |

In the rest of this document, most parallel examples will make use of the above shortcuts: ø is used as a placeholder for the future ¤ and IÏ in place of ∥¨. Let us take a closer look at them:

### Parallel Each

A very simple example, which illustrates the potential of isolates very well, is the behaviour of parallel invocations of the system function ⎕DL, which consumes almost no system resources, but takes a fixed amount of elapsed time. In “normal” Dyalog APL:

T←⎕AI ⋄ ⎕←⎕DL¨8⍴3 ⋄ ⎕←⎕AI-T  
3.008 3.004 3.005 3.004 3.007 3.009 3.007 3.007  
0 7125 24054 0

The second line of output shows that the elapsed time for this expression is very slightly more than 24 seconds, which should be no surprise: the each operator applies the ⎕DL function sequentially to each of the 8 elements in the right argument.

In v14.0, we are able to run the 8 delays in parallel using the operator named IÏ, which is a cover for isolate.llEach - and represents the future primitive operator pair ∥¨:

T←⎕AI ⋄ ⎕DL IÏ 8⍴3 ⋄ ⎕AI-T  
3.002 3.002 3.002 3.004 3.004 3.003 3.004 3.003  
0 3000 3051 0

Although we have achieved almost “perfect” parallelisation, we can see from the timings that there is a slight overhead due to the cost of creating the isolates and communicating with them – on the author’s laptop roughly 5-6ms per function invocation.


Of course, parallel invocations of ⎕DL are not THAT useful. Let us examine what happens if we use a (very slightly) more interesting example. Consider the following function which loops a given number of times, does some fairly hard work, and returns the number of elapsed milliseconds as its result:

∇ r←loop n;m  
[1] m←n  
[2] r←3⊃⎕AI  
[3] :Repeat ⋄ n←n-1  
[4] work←≢∪10000?10000  
[5] :Until n≤0  
[6] r←(3⊃⎕AI)-r  
 ∇  
  
Unlike ⎕DL, this function consumes a large amount of CPU time compared – it is in a tight CPU loop. Let us repeat an experiment similar to the one above:

T←⎕AI ⋄ loop¨ 4⍴1E4 ⋄ ⎕AI-T  
2958 3036 3039 3002  
0 12047 12040

T←⎕AI ⋄ loop IÏ 4⍴1E4 ⋄ ⎕AI-T  
6561 6621 6631 6611  
0 5829 6664 0

Windows Task Manager shows the profiles of these two executions below: The first run taking 12 seconds at about 30% reported utilization, the second 6 seconds at 100%.



We can see that the parallel invocations come fairly close to running twice as fast, completing the four calls to loop in 55% of the time (6.6 vs 12.0 seconds). This is not a bad result on the machine where this was run, a fairly typical laptop of the current era – with a 1.6Ghz Intel Core i5-4200 with 2 cores (split into 4 logical processors). Although this kind of machine has two cores, they share the same memory sub-system, so the cores will compete for memory accesses and slow each other down.

### Explicit Isolates

When a function is invoked under parallel each, an empty isolate is created for it to run in, and the isolate is destroyed when execution completes. In some situations, it makes sense to create a number of isolates ahead of time, and use them to execute more than one expression. Isolates are created using the function ø, which represents the future primitive function ¤. The right argument can be a namespace to clone, or an empty vector to create an empty namespace. For example:

is1←ø '' ⍝ Create an empty isolate  
 is2←ø '' ⍝ Another one  
 is1.X←1 2 3 4 ⍝ Give the name X a value in 1st isolate  
 is2.X←5 6 7 8 9 ⍝ A different value in the 2nd isolate  
 isolates←is1 is2 ⍝ References to isolates can form an array  
 isolates.(+/X) ⍝ Execute (+/X) in 2 isolates in parallel  
10 35  
 T←⎕AI ⋄ isolates.(⎕DL 3) ⋄ ⎕AI-T  
3.003 3.003  
0 3000 3010 0

The last example shows us that, compared to parallel each, the overhead is somewhat lower when pre-existing isolates are used (about 4ms in this case). We can repeat the example with our loop function:

isolates←isolates,ø¨'' ''⍝ Add another 2 isolates  
 isolates.⎕FX ⊂⎕CR 'loop' ⍝ Fix loop function in each isolate  
 loop loop loop loop   
 T←⎕AI ⋄ isolates.loop 1E4 ⋄ ⎕AI-T  
6714 6783 6801 6788  
0 5890 6814 0

In this case, we ran slower than when we used IÏ, probably due to other things going on in the background.

The performance target for futures and isolates in version 14.0 is that they should be efficient for parallelised units of work that consume at least 100ms. With overheads in the region of 4-6ms per call, this seems within reach.

### A More Realistic Example

This section will be expanded to show an example which does some analysis of web pages. Main building blocks is a function which downloads web page contents

∇ r←GetPages addresses;⎕USING;srcUri;client;r;address;i  
[1] ⎕USING←'System,mscorlib.dll' 'System.Net,System.dll'  
[2]  
[3] r←(⍴addresses)⍴⊂''  
[4] client←⎕NEW WebClient ⍬  
[5]  
[6] :For i :In ⍳⍴addresses  
[7] srcUri←⎕NEW Uri(addresses[i])  
[8] r[i]←⊂client.DownloadString srcUri  
[9] :EndFor  
 ∇

text←⊃GetPages,⊂'http://www.usnpl.com/manews.php'  
z←('(<a href=")(.\*?)(.com/">)'⎕S'\2.com/') text

z is now a list of newspaper web sites in Massachusetts, and we’ll do a some analysis of each front page.

# Configuration

The isolate namespace has a number of configuration options which control how isolates are started and managed. Options are queried and set using the Config function, for example:

isolate.Config 'workspace' 'c:\temp\myapp\myapp.dws'  
c:\temp\myapp\myapp.dws

The current set of supported options is:

|  |  |
| --- | --- |
| **Name and Default Value** | **Description** |
| debug←0 | Cut back on error, or allow isolate to suspend |
| drc←# | Location of CONGA namespace to use |
| workspace←'isolate' | Workspace to load when starting new isolates |
| listen←0 | Controls whether isolates may issue callbacks to parent process (adds significant overhead to isolate creation and teardown) |
| processors←4 | Number of processors (under Windows, determined automatically – this option is likely to change) |
| processes←1 | The number of processes to start per process |
| runtime←'R'∊3⊃'.'⎕WG'APLVersion' | Whether to run isolates using a runtime engine |

### Configuration Options

This section contains a more detailed discussion of the configuration options (and is work in progress):

### debug

All public fns and ops set an error guard as:

trapErr''::signal''

If options.debug is 0 (the default) then trapErr'' returns 0 so all errors are trapped and signalled back to the session.

If 1 then trapErr'' is ⍬, there is no trap and errors are signalled at the point of error.

### drc

If drc is # (the default) we check to see if #.DRC exists and copy if not. Otherwise drc must be a ref to the extant DRC namespace.

### workspace

This is the workspace to be ⎕LOADed by APLProcess (default "isolate") that must contain the isolate namespace and call 'isolate.ynys.isoStart ⍬' in its ⎕LX. It should be in one of the folders defined in [Options]-[Configure...]-[Workspace] in the session menubar or be specified with a full path.

### listen

Whether the isolates will be enabled to call back to the active ws to request further data &c. (default 0.)

### processors

The number of prosessors in the machine. Currently available from Windows but default 4 elsewhere.

### processes

The number of processes that will be started per processor in the machine. (default 1.)

### runtime

Whether the runtime equivalent of the active interpreter should be started for the slave processes. If the active interpreter (the default) is runtime then runtime anyway.

# Advanced Topics

This and all following sections are under construction, and only contains notes of topics to be discussed.

Queueing: Although isolates and the main process can both be using multiple APL threads (created using the spawn operator &), all calls INTO an isolate are placed in a queue and only a single call into an isolate will be running at any one time. Even if a future has been passed back as a “result” to the caller, the isolate will not start processing the next expression until the previous one has finished. The same is true for calls back to the main process from isolates: Only one such call back will be active at any one time.

* Load Balancing
* Remote Servers
* Running as a Windows Service
* Integrating with your application: LX, workspace to load, CONGA/DRC
* Runtime vs Devt: Startup speed
* Unix?
* The “peek” I-Beam
* Reaching back into the main process to read/modify globals
* Making “callbacks” into the main process (SQL query)
* Discussion of the old “parallel” workspace vs the new features

# Troubleshooting

This section also very much Work In Progress.

Hints and tips… Common error messages and things that go wrong.

Remember to “resume all threads”!

### Differences between Isolates and Namespaces

The following example is intended to demonstrate some of the differences between isolates and namespaces:

### Trapped Errors

(see section 8 on debugging isolates for more information)

### Unexpected Output

ns←⎕NS '' ⍝ Create an empty isolate  
 is←isolate.New '' ⍝ Create an empty isolate  
 ns.(X←10?10) ⍝ Run an expression in ns  
 is.(X←10?10) ⍝ With an isolate, this produces output  
6 9 3 4 8 2 7 1 5 10

### File Ties Not Shared with Isolates

Unlike namespaces, isolates are separate processes, so they do not share any resources that belong to the current process, such as file ties, loaded libraries, TCP sockets, etc.

'file1' ⎕fstie 0 ⍝ Tie a file in main process  
1  
 'file2' ns.⎕fstie 0 ⍝ Tie a file “in” a namespace  
2  
 'file1' is.⎕fstie 0 ⍝ Tie first file in the isolate  
1  
   
 ⎕fnames,⍪⎕fnums ⍝ root and ns are in the same process  
file1 1  
file2 2

is.(⎕fnames,⍪⎕fnums) ⍝ isolate is a separate process  
file1 1

# Debugging Isolates

(more to come)

# Appendix A: Function and Operator Reference

This section also very much Work In Progress.

##### r←StartServer ⍵

Run an isolate server on one machine to be used by one or more others.

This must be the first use of the isolate namespace in the session.

Output should be similar to:

,------------------------------------------------------------------------,  
| isolate.StartServer'' |  
|Server 'ISO7051', listening on port 7051 |  
| Handler thread started: 1 |  
| Thread 1 is now handing server 'ISO7051'. |  
| |  
| IP Address: 192.168.0.2 |  
| IP Ports: 7052 7053 7054 7055 |  
| |  
|Enter the following in another session, in one or more another machines:|  
| |  
| #.isolate.AddServer '192.168.0.2' (7052-⎕IO-⍳4) |  
'------------------------------------------------------------------------'

##### r←AddServer ⍵

use isolate server started in another machine

⍵ address ports

address ip-address of host where isolates will reside.

ports ports listening for isolate creation and execution.

The argument will be given as output from the session in the server machine when started with:

isolate.StartServer''

Multiple servers can be started in different machines and used by one or vice versa depending on resources available.

isolates can be used as usual with New, llEach &c. but expressions will be evaluated in the other machine.

##### r←New ⍵

models isolate primitive: ¤

⍵ source

source code ∧/∨ data to be copied to isolate.

ref or namelist expected to be qualified relative to caller.

caller space from which this fn was called.

when this is primitive both source & caller will be a matter of course.

← proxy

proxy visible component of isolate.

anonymous space child of caller.

contains copies of iSyntax & iEvaluate, and refs - iSource to source, iCaller to the caller, iSpace to this space, iCarus - an instance of the "suicide" class and iD - containing the isolate id, the DRC client id, the port and the remote process id.

##### r←Config ⍵

query or set configuration options.

⍵ name | name value

name one of the names defined in the setDefaults function - see Configuration options below.

### Operators

##### r←⍺ (⍺⍺ ll) ⍵

parallel - models ⍺ ⍺⍺∥ ⍵

⍺ optional left argument to ⍺⍺

⍺⍺ function to run in an ephemeral isolate.

⍵ right arg to ⍺⍺

← future - result of ⍺⍺ execured in isolate.

##### r←⍺ (⍺⍺ llEach) ⍵

parallel each - models ⍺ ⍺⍺∥¨ ⍵

⍺ optional array itemwise compatible with ⍵; it's items are in the left domain of ⍺⍺.

⍺⍺ function presumed to be ambivalent or dyadic if ⍺ is supplied or monadic if not.

⍵ array whose items are in the right domain of ⍺⍺.

← array of futures with shape ←→ ⍴⍺⊢¨⍵ or ⍴⍵

##### r←⍺ (⍺⍺ llOuter) ⍵

parallel outer product - models ⍺ ∘.(⍺⍺∥) ⍵

⍺ array whose items are in the left domain of ⍺⍺.

⍺⍺ dyadic function.

⍵ array whose items are in the right domain of ⍺⍺.

← the result is an array of futures with shape ←→ (⍴⍺),⍴⍵

⍺⍺ is applied between all possible pairs of items of ⍺ and ⍵ after

the function and values have been transferred to an array of

ephemeral isolates created for this one use.

##### r←⍺ (⍺⍺ llRank ⍵⍵) ⍵

parallel rank - models ⍺ (⍺⍺∥⍤⍵⍵) ⍵

⍺ optional array framewise compatible with ⍵; it's cells as defined by ⍵⍵ are in the left domain of ⍺⍺.

⍺⍺ function presumed to be ambivalent or dyadic if ⍺ is supplied or monadic if not.

⍵⍵ integer scalar or 1, 2 or 3 item vector defining the ranks of the cells to or between which function ⍺⍺ will be applied.

⍵ array whose cells as defined by ⍵⍵ are in the right domain of ⍺⍺

← array of futures with shape determined by combination of ⍵⍵ and the sahpes of ⍺ amd/or ⍵

⍺⍺ is applied between corresponding cells of ⍺ and ⍵ or to the cells of ⍵ after the function and values have been transferred to an array of ephemeral isolates created for this one use.

# Appendix Z: Implementation Notes

Currently contains un-edited implementation notes… Do not read ☺.

All contained in a single ns-tree - #.isolate - but aim to be relocatable as:

'#.isolate' #.myns.⎕CY 'isolate'

The isolate proxy returned by New is a container space created by ⎕NS in the caller having had 1∘(700⌶) applied to it.

It contains the special functions: "iSyntax" & "iEvaluate", additional function iSend and a number of namespaces.

Data spaces:

session - created and populated by Init, it contains all constants & variables except those in:

options - created and populated by setDefaults, it contains all user options. Maintained by Config.

Tables:

session.procs

stores process instances and contact details in four columns:

proc-id; proc-inst(0); host-addr; port-no

proc-id integer incremented from zero when a process is started or made available.

proc-inst instance of APLProcess if local or 0 placeholder if remote

host-addr IP-address of machine where is process

port-no port-number on which process listening; incremented from first available multiple of 7051

session.assoc

associates isolates with particular processes in two columns:

isolate-id; proc-id

isolate-id integer incremented from "random" seed; also in iD namespace in proxy and sent to isolate; names remote space as: 'IsoNNNN'

proc-id as session.procs

-----------------------------------------------------------------

iSyntax - copied to proxy

return name class and syntax code of supplied name

⍵ simple name

← class, syntax

class ⎕NC of name in source space.

We can only know the nameclass and syntax of the items as they

existed prior to being transferred to the remote process.

syntax 2⊥1= result ambivalent dyadic rarg 0 0

--------------------------------------------------------------------------

iEvaluate - copied to proxy

execute expression supplied to isolate

⍺ | ⍵ - n is the syntax code supplied by "syntax"

|

| 2 n arrayname

| 2 n arrayname newvalue

| 2 n arrayname (PropertyArguments : Indexers IndexersSpecified)

| 2 n arrayname (PropertyArguments : Indexers IndexersSpecified

| NewValue)

| 3 n niladname

| 3 n (expression)

| 3 n {monad} rarg

larg | 3 n {dyad} rarg

| 3 n monadname rarg

larg | 3 n dyadname rarg

RPCServer only permits a monadic fname and rarg to an existing function in the remote ws so we give it 'execute' with nested vector rarg as:

a | b | c | d | e

0 | array | | |

0 | nilad | | |

0 | (expr) | | |

1 | monad | rarg | |

2 | larg | dyad | rarg |

3 | array | value | |

4 | array | indices | axes |

5 | array | indices | axes | value

If the expression causes an error that is trapped in the remote

process it is passed back as ⎕EN ⎕DM that is signalled .

1. Including Dyalog APL, which provides a spawn operator (&) the ⎕TGET/⎕TPUT/⎕TSYNC family of system functions, and the :Hold … :EndHold control structure. [↑](#footnote-ref-1)
2. In fact, as we shall see later, an isolate *could* be running on a completely different machine, which might not even be running the same operating system or be able to see the same file system as the parent process. [↑](#footnote-ref-2)
3. Might change before release – or the operators might be renamed: In the current model, to avoid blocking in order to “mix” the results into the complete result matrix, llRank and llKey return nested arrays of futures, which need a final “mix” to produce the result that the primitive operator would return. [↑](#footnote-ref-3)